ТЕМА:

///////////////////////////////////////////////////////////////
//module which generates video sync impulses
///////////////////////////////////////////////////////////////

module hvsync (
	// inputs:
	input wire clock,
	
	// outputs:
	output reg line,
	output reg frame,
	output reg hsync,
	output reg vsync
	);

//variables	
reg [9:0]char_count;
reg [10:0]line_count;
reg end_of_line;
reg [1:0]pixel_st;
reg [1:0]line_st;
reg end_of_frame;

//permanent comb computations:
always @*
begin
	//horizontal processing
	if(char_count < 320)
		pixel_st = 0; //active video
	else
	if(char_count < 328)
		pixel_st = 1; //front porch
	else
	if(char_count < 376)
		pixel_st = 2; //hsync impuls
	else
		pixel_st = 3; //back porch

	if(char_count < 400)
		end_of_line = 0;
	else
		end_of_line = 1;

	//vert processing
	if(line_count < 480)
		line_st = 0; //active video lines
	else
	if(line_count < 490)
		line_st = 1; //front porch
	else
	if(line_count < 492)
		line_st = 2; //vsync impuls
	else
		line_st = 3; //front porch

	if(line_count < 525)
		end_of_frame = 0;
	else
		end_of_frame = 1;			
end

//synchronous process
always @(posedge clock)
begin
	hsync <= (pixel_st==2'b10);
	vsync <= (line_st==2'b10);
	line <= (pixel_st==2'b0);
	frame <= (line_st==2'b0);
	
	if(end_of_line)
	begin
		char_count <= 0;
			
		if(end_of_frame)
			line_count <= 0;
		else
			line_count <= line_count + 1'b1;
	end
	else
	begin		
		char_count <= char_count + 1'b1;
	end
end

endmodule